E-Tablolarda Google Form Yanıtlarıyla Formüller Nasıl Kullanılır?

İnsanlar Google Formunuzu gönderdiğinde, Google E-Tablosuna form yanıtlarını depolayan yeni bir satır eklenir. Bu e-tablo satırı, bir Zaman Damgası sütunu, formun gönderildiği gerçek tarihi içerir ve sayfadaki diğer sütunlar, sütun başına bir tane olmak üzere, kullanıcının tüm yanıtlarını içerir.

Google Formlar sayfasını, formül alanlarını da içerecek şekilde genişletebilirsiniz ve hücre değerleri, Google Formu tarafından sayfaya her yeni satır eklendiğinde otomatik olarak hesaplanır. Örneğin:

• Her form yanıtına otomatik artan ancak sıralı bir kimlik atayan bir otomatik sayı formülünüz olabilir. Faturalandırma için Google Formlar'ı kullanırken faydalı olabilir.
• Müşteri sipariş formları için Google E-Tablolar'da ürün seçimi, ülke (vergi oranları farklıdır) ve formda seçilen miktar bazında toplam tutarın hesaplanması için formül yazılabilir.
• Otel rezervasyon formları için, müşteri tarafından Google Form'da doldurulan giriş ve çıkış tarihine göre oda kirasını otomatik olarak bir formül hesaplayabilir.
• Kısa sınavlar için bir öğretmen, forma girilen değerleri gerçek cevaplarla eşleştirerek ve puanlar atayarak öğrencinin nihai puanını otomatik olarak hesaplayabilir.
• Bir kullanıcı birden fazla form gönderimi yaptıysa, bir formül, bir kullanıcı tarafından form gönderilir gönderilmez yapılan toplam giriş sayısını belirlemenize yardımcı olabilir.

Google Formlar için Google E-Tablolar Formülleri

Bu adım adım kılavuzda, Google Formlar ile ilişkilendirilmiş formülleri Google E-Tablolara nasıl ekleyeceğinizi öğreneceksiniz. Yanıt satırlarındaki karşılık gelen hücre değerleri, yeni bir yanıt gönderildiğinde otomatik olarak hesaplanacaktır.

Neyi başarmaya çalıştığımızı daha iyi anlamak için bu Google Formunu açın ve bir yanıt gönderin. Ardından, bu Google E-Tablosunu açın ve yanıtınızı yeni bir satırda bulacaksınız. FK sütunları formüller kullanılarak otomatik olarak doldurulur.

Aşağıdaki tüm örnekler, Google E-Tablolar'ın ArrayFormula işlevini kullanacaktır, ancak bu örneklerin bazıları FILTER işlevi kullanılarak da yazılabilir.

Benzersiz Kimliğe Sahip Otomatik Numara Formu Yanıtları

Form yanıtlarını depolayan Google E-Tablosunu açın, ilk boş sütuna gidin ve aşağıdaki formülü boş sütunun 1 numaralı satırına kopyalayıp yapıştırın.

 =ArrayFormula( IFS( ROW(A:A)=1, "Invoice ID", LEN(A:A)=0, IFERROR(1/0), LEN(A:A)>0, LEFT(CONCAT(REPT("0",5), ROW(A:A) -1),6) ) )

ROW() işlevi, geçerli yanıt satırının satır numarasını döndürür. Fatura Sütununda ilk satır için 1 döndürür ve böylece ilk satırdaki sütun başlığını belirleriz. Sonraki satırlar için, satırın ilk sütunu (genellikle Zaman Damgası) boş değilse, fatura kimliği otomatik olarak oluşturulur.

Kimlikler 00001 , 00002 gibi olacaktır. Yalnızca formülü sütunun ilk satırına yerleştirmeniz gerekir ve sütundaki diğer tüm satırları otomatik olarak doldurur.

IFERROR işlevi, bir hata değeri değilse ilk bağımsız değişkeni, aksi takdirde varsa ikinci bağımsız değişkeni veya ikinci bağımsız değişken yoksa bir boşluk döndürür. Yani bu durumda 1/0 bir hatadır ve bu nedenle her zaman boş bir değer döndürür.

Google Formlar için Tarih Hesaplama Formülü

Google Formunuzun iki tarih alanı vardır - giriş tarihi ve çıkış tarihi. Otel fiyatları her sezon değişiklik gösterebilir, bu nedenle Google E-Tablosunda aylık oda kirasını gösteren ayrı bir tablonuz olur.

Google E-Tablosundaki C Sütunu, giriş tarihine ilişkin yanıtları tutarken, D sütunu çıkış tarihlerini saklar.

 =ArrayFormula( IF(ROW(A:A) = 1, "Room Rent", IF(NOT(ISBLANK(A:A)), (D:D - C:C) * VLOOKUP(MONTH(D:D), 'Room Rates'!$B$2:$C$13,2, TRUE), "" ) ) )

Formüller, form yanıtında belirtilen seyahat tarihi için oda fiyatlarını almak için VLOOKUP kullanır ve ardından oda kirasını kalış süresiyle çarparak oda kirasını hesaplar.

Aynı formül VLOOKUP yerine IFS ile de yazılabilir.

 =ArrayFormula( IF(ROW(A:A) = 1, "Room Rent", IFS(ISBLANK(C:C), "", MONTH(C:C) < 2, 299, MONTH(C:C) < 5, 499, MONTH(C:C) < 9, 699, TRUE, 199 ) ) )

Fatura Değerine Göre Vergi Tutarı Hesaplayın

Bu yaklaşımda, FILTER işlevini kullanacağız ve bu, IF işlevini kullanmaktan daha az karmaşık bir formüle yol açabilir. Dezavantajı, sütun başlığını 1. satıra yazmanız ve formülleri 2. satıra yapıştırmanız gerektiğidir (bu nedenle formülün çalışması için bir form yanıtı olmalıdır).

 =ArrayFormula(FILTER(E2:E, E2:E<>"")*1.35)

Burada fatura değerine %35 vergi uyguluyoruz ve bu formül ekran görüntüsünde gösterildiği gibi “Vergi Tutarı” başlıklı sütunun 2. satırına eklenmelidir.

Google Formlar'da Sınav Puanları Atayın

Büyük elma olarak bilinen şehir hangisidir? Bu, öğrencilerin New York, New York City, NYC gibi yanıtlar verebilmeleri için Google Formlar'da kısa yanıtlı bir sorudur ve yanıtlar yine de doğru olacaktır. Öğretmen doğru cevaba 10 puan vermelidir.

 =ArrayFormula( IF(ROW(A:A) = 1, "Quiz Score", IFS( ISBLANK(A:A), "", REGEXMATCH(LOWER({B:B}), "new\s?york"), 10, {B:B} = "NYC", 10, TRUE, 0 ) ) )

Bu formülde, programlamada IF THEN deyimine benzeyen IFS fonksiyonunu kullanıyoruz. Düzenli ifadeler kullanarak New York, New York, newyork gibi değerleri tek seferde eşleştirmek için REGEXMATCH kullanıyoruz.

IFS işlevi, koşullardan hiçbiri doğru değilse bir NA döndürür, bu nedenle, önceki koşullardan hiçbiri eşleşmediğinde her zaman true olarak değerlendirilecek ve 0 değerini döndürecek bir TRUE denetimi ekleriz.

Form Yanıtlayanın Adını Çıkarın

Kullanıcıdan tam adının tamamını soran bir form alanınız varsa, tam addan adı çıkarmak için Google E-Tablolar işlevini kullanabilir ve bu alanı kişiselleştirilmiş e-postalar göndermek için kullanabilirsiniz.

 =ArrayFormula( IFS( ROW(A:A)=1, "First Name", LEN(A:A)=0, IFERROR(1/0), LEN(A:A)>0, PROPER(REGEXEXTRACT(B:B, "^[^\s+]+")) ) )

Ad alanındaki ilk boşluktan önceki dizeyi getirmek için burada RegexExtract yöntemini kullandık. PROPER işlevi, kullanıcının adını küçük harfle girmesi durumunda adın ilk harfini büyük harf yapacaktır.

Yinelenen Google Form Gönderimlerini Bul

Google Formunuz koleksiyon e-posta adresleriyse, aynı kullanıcı tarafından birden çok kez gönderilen yanıtları hızlı bir şekilde algılamak için bu alanı kullanabilirsiniz.

 =ArrayFormula( IFS( ROW(A:A)=1, "Is Duplicate Entry?", LEN(A:A)=0, IFERROR(1/0), LEN(A:A)>0, IF(COUNTIF(B:B, B:B) > 1, "YES", "") ) )

B Sütununun form yanıtlayanların e-posta adreslerini sakladığını varsayarsak, COUNTIF işlevini yanıtlar e-tablomuzdaki yinelenen girişleri hızlı bir şekilde işaretlemek için kullanabiliriz. Yinelenen girişler olabilecek satırları vurgulamak için E-Tablolar'da koşullu biçimlendirmeyi de kullanabilirsiniz.

Otomatik Doldurma Değerleriyle E-posta Formu Yanıtları

Form yanıtlayanlara otomatik olarak bir e-posta göndermek için Document Studio'yu kullanabilirsiniz. E-posta, formül değerleri Google E-Tablosu tarafından otomatik olarak doldurulduktan sonra gönderilir. Orijinal form yanıtı ve hesaplanan değerler de oluşturulan PDF belgesine dahil edilebilir.